**期指30分钟周期CTA策略**

策略主要逻辑：强上涨状态中不做空；强下跌状态中不做多。在非强上涨状态时，超买时的向下破位更容易下跌；在非强下跌状态时，超买状态下的上涨可以追。

**一、强趋势状态的判断**

在日线周期中，判断强趋势的标准：单日出现大幅上涨或大幅下跌、价格连续多日在均线之上。具体地：

1、前期一段时间出现日涨幅超过BigBarPercent%的Bar，则认为强上涨趋势；出现日跌幅低于-BigBarPercent%的Bar，则认为强下跌趋势，假设出现大Bar后，在随后的DelayDay个交易日，延续趋势状态。

参数：BigBarPercent(2.5)、DelayDay(2)

2、日线周期，收盘价持续CountBar个Bar在均线之上，且最后第CountBar日的收盘价超过MA的LastDayDiff%的幅度时，确定强上涨趋势；收盘价持续CountBar个Bar在均线之下，且最后第CountBar日的收盘价低于MA的LastDayDiff%的幅度时，确定强下跌趋势。

参数：MALength(5)、CountBar(6)、LastDayDiff(1)

**二、短期超买指标和上下轨**

在30分钟周期，计算两个KDJ指标，基于Length1和Length2两个周期参数，比较两个KDJ指标中J值的差异JDiff。

在30分钟周期，计算Length周期的最高价和最低价形成的上轨UpperBand和下轨LowerBand。

参数：Length1(9)、Length2(6)、Length(4)

**三、出入场规则**

1、非强下跌状态中，当前Bar突破前期上轨UpperBand，Close[1]>High[2]，JDiff>0时，平空开多；

2、非强上涨状态中，当前Bar跌破前期下轨LowerBand，Close[1]<Low[2]，JDiff>0时，平多开空。

3、出场条件：ATR初始止损+跟踪止盈

4、其他：10点前不交易

参数：TrailStart1(1)、TrailStop1(80)、ATRK(3);

附：TB部分代码

Params

Numeric MALength(5);

Numeric CountBar(6);

Numeric LastDayDiff(1);

Numeric BigBarPercent(2.5);

Numeric RestDay(2);

Numeric Length1(9);

Numeric Length2(6);

Numeric Length(4);

Numeric TrailStart1(1);

Numeric TrailStop1(80);

Numeric ATRK(3);

Numeric EntryLots(1);

Vars

BoolSeries StrongUp;

BoolSeries StrongDown;

Bool UpTrend;

Bool DownTrend;

NumericSeries TrendConfirm;

NumericSeries RSV1;

NumericSeries RSV2;

NumericSeries K1;

NumericSeries D1;

NumericSeries J1;

NumericSeries K2;

NumericSeries D2;

NumericSeries J2;

NumericSeries UpperBand;

NumericSeries LowerBand;

NumericSeries JDiff;

BoolSeries TradeTime;

NumericSeries ATRValue;

NumericSeries TempHigh;

NumericSeries TempLow;

Numeric StopLine;

Begin

TrendConfirm=IIF(Date<>Date[1],DayTrendFilter(MALength,CountBar,LastDayDiff,BigBarPercent,RestDay,UpTrend,DownTrend),0);

StrongUp=UpTrend;

StrongDown=DownTrend;

TradeTime=Time>=10/100 && Time<15/100;

RSV1=(High[1]-Lowest(Low[1],Length1))/(Highest(High[1],Length1)-Lowest(Low[1],Length1))\*100;

K1=XAverage(RSV1,Length2);

D1=XAverage(K1,Length2);

J1=3\*K1-2\*D1;

ATRValue=AvgTrueRange(14);

RSV2=(Highest(High[1],Length1)-Low[1])/(Highest(High[1],Length1)-Lowest(Low[1],Length1))\*100;

K2=XAverage(RSV2,Length2);

D2=XAverage(K2,Length2);

J2=3\*K2-2\*D2;

JDiff=J1-J2;

UpperBand=Highest(High[1],Length);

LowerBand=Lowest(Low[1],Length);

If(MarketPosition!=1 && JDiff>=0 && High>=UpperBand && Close[1]>=High[2] && TradeTime && StrongDown==False)

Buy(EntryLots,Max(UpperBand,Open));

If(MarketPosition!=-1 && JDiff>=0 && Low<=LowerBand && Close[1]<=Low[2] && TradeTime && StrongUp==False)

SellShort(EntryLots,Min(LowerBand,Open));

TempHigh=Highest(High[1],BarsSinceEntry);

TempLow=Lowest(Low[1],BarsSinceEntry);

If(MarketPosition==1 && BarsSinceEntry>0)

{

If(TempHigh>LastEntryPrice\*(1+TrailStart1\*0.01))

{

StopLine=TempHigh-(TempHigh-LastEntryPrice)\*TrailStop1\*0.01;

If(Low<StopLine)

Sell(EntryLots,Min(StopLine,Open));

}

Else

If(TempHigh<=LastEntryPrice\*(1+TrailStart1\*0.01) && TradeTime)

{

StopLine=LastEntryPrice-ATRK\*ATRValue[1];

If(Low<StopLine)

Sell(EntryLots,Min(StopLine,Open));

}

}

If(MarketPosition==-1 && BarsSinceEntry>0)

{

If(TempLow<LastEntryPrice\*(1-TrailStart1\*0.01))

{

StopLine=TempLow+(LastEntryPrice-TempLow)\*TrailStop1\*0.01;

If(High>StopLine)

BuyToCover(EntryLots,Max(StopLine,Open));

}

Else

If(TempLow>=LastEntryPrice\*(1-TrailStart1\*0.01) && TradeTime)

{

StopLine=LastEntryPrice+ATRK\*ATRValue[1];

If(High>StopLine)

BuyToCover(EntryLots,Max(StopLine,Open));

}

}

End